Possible to implement formmail or a contact form?

[Attention]

Hello

Im trying to implement a simple contact flash php script, it hasnt worked so far, i get it to load but it doesnt send. The form works on it's own when not implemented in megazine.

Anyone have luck with this?`

[Florian Nücke]

Hi,

technically it should be possible. I'm almost sure I already had someone trying this and finally succeeding, too.
Do you test this locally? If so, try moving it to a server (or install wamp and test it on that local server), might be because of the security sandbox...

Regards,
Florian

[maxie]

I cannot get them working here, either. It is a pity. A form for the book would be a nice add-on. I have tried several forms/scripts:

- Mailform versions using SWF, XML and PHP would usually say that they cannot find the XML file, although it is in the same directory. (Is there a conflict between the megazine.xml and the xml file for the form?)
- Another mailform without an additional XML, i.e. using "only" the SWF and PHP (this one: http://maxie-online.de/#/32) "pretends" to be sending, but actually it does not send at all.

All the forms I tried work fine when the SWF is embedded in a  HTML page. But as soon as I take the SWF and put it on a book page, the form would not work any more.

It would be nice to hear from those who got their  form working to share with us how they did it.

Kind regards,
Maxie

[Florian Nücke]

Hmm... most likely some sandboxing problem. I'll have a look into this myself when I find the time.

[Attention]

any recent resolution on this? would love to hear

[Florian Nücke]

Haven't tried this with the 1.38 version, but in the 2.x version the following works just fine:

ActionScript 3.0 part (the swf with the form loaded into the book):

Code: (actionscript3)

stop();
 
// request related vars and setup
 
var variables:URLVariables = new URLVariables();
var variableLoader:URLLoader = new URLLoader();
var variableSend:URLRequest;
 
import de.mightypirates.megazine.interfaces.IMegaZine;
 
// initialize request var with path relative to megazine.swf
function megazineSetup(megazine:IMegaZine):void {
	variableSend = new URLRequest(megazine.getAbsPath("form_eval.php"));
	variableSend.method = URLRequestMethod.POST;
	variableSend.data = variables;
}
 
// perform the request
function sendFormData():void {
	variables.username = txtName.text;
	variables.email = txtMail.text;
	variableLoader.load(variableSend);
}
 
// build form
 
graphics.beginFill(0, 0.5);
graphics.drawRect(0, 0, 100, 75);
graphics.endFill();
var txtName:TextField = new TextField();
txtName.width = 100;
txtName.height = 25;
txtName.type = TextFieldType.INPUT;
txtName.background = true;
txtName.border = true;
addChild(txtName);
var txtMail:TextField = new TextField();
txtMail.width = 100;
txtMail.height = 25;
txtMail.type = TextFieldType.INPUT;
txtMail.background = true;
txtMail.border = true;
txtMail.y = 25;
addChild(txtMail);
var btnSend:SimpleButton = new SimpleButton(buildState(0), buildState(1), buildState(2), buildState(0));
btnSend.y = 50;
addChild(btnSend);
 
// build button states...
function buildState(type:int):DisplayObject {
	var s:Sprite = new Sprite();
	switch (type) {
		case 0:
			s.graphics.beginFill(0xFF0000);
			break;
		case 1:
			s.graphics.beginFill(0x00FF00);
			break;
		case 2:
			s.graphics.beginFill(0x0000FF);
			break;
	}
	s.graphics.drawRect(0, 0, 50, 25);
	s.graphics.endFill();
	return s;
}
 
// gui event stuff
btnSend.addEventListener(MouseEvent.CLICK, handleButtonClick);
 
function handleButtonClick(e:MouseEvent):void {
	sendFormData();
}

PHP part for testing if the data arrives:

Code: (php)

<?php
$fileh = fopen("formdata.txt", 'a');
fwrite($fileh, $_REQUEST['username'] . ": " . $_REQUEST['email'] . "\n");
fclose($fileh);
?>

Just be sure to test this on a server and not locally (in the sense of, test it through a server, even if it's running on your machine, e.g. wamp - meaning the url must start with http:// not with file:///).

[Attention]

Hm could you be so kind to post the .flv file?

i tried pasting this code in flash root, but im guessing i would have to make the graphics - input boxes etc?

[Florian Nücke]

The second half of the code does the form building (after // build form)... I mean, I can post the fla, but it's just an new document with the code pasted in

You're probably missing the interface (IMegaZine)... either get it and put it to the proper location, oder replace all occurences with '*' and remove the import.

(i.e.

Code: (actionscript3)

import de.mightypirates.megazine.interfaces.IMegaZine;
 
// initialize request var with path relative to megazine.swf
function megazineSetup(megazine:IMegaZine):void {
    variableSend = new URLRequest(megazine.getAbsPath("form_eval.php"));
    variableSend.method = URLRequestMethod.POST;
    variableSend.data = variables;
}

becomes

Code: (actionscript3)

// initialize request var with path relative to megazine.swf
function megazineSetup(megazine:*):void {
    variableSend = new URLRequest(megazine.getAbsPath("form_eval.php"));
    variableSend.method = URLRequestMethod.POST;
    variableSend.data = variables;
}

)

[Afroshok]

Hi Florian,

What is the method for this now with the 2.0 RC. the above solution was perhaps for 1.38?

[Florian Nücke]

Haven't tried this with the 1.38 version, but in the 2.x version the following works just fine:
[snip]

So no, the above was not explicitly for 1.38 (although it should work with that, too). In 2.x it definitely works.

[Attention]

alright still no luck - is there any easy way just to adapt an exisiting contact as3 form now with the new megazine?

or has anyone got florians to work and is willing to post an example?

[Attention]

Alright got it working! sortof!

im not very sharp when it comes to php and as3 but i have a basic knowledge sort of

what should be in formdata.txt? and how should i format it ?

where is send to in this php?

      <?php

      $fileh = fopen("formdata.txt", 'a');

      fwrite($fileh, $_REQUEST['username'] . ": " . $_REQUEST['email'] . "\n");

      fclose($fileh);

      ?>

[Attention]

Please help

getting desperate!

Im willing to exchange some design skills in order to get some help on this contact form / if anyones interested!

[Florian Nücke]

The PHP code is just an example. It just opens a text file (named formdata.txt) and writes the received data (from the $_REQUEST variable) into it.

If you don't know how to process the form data on the serverside (i.e. in the PHP / ASP / JSP / Python / Perl / whatever you use) try your favorite
search machine, and it'll gladly help you, I'm sure [because if you're at that point the data get's sent, so it's no longer a Flash / MegaZine3 related
issue; you might as well try a general Flash forum for that, then]

[Attention]

Ok florian still struggling with this tried adopting a simple as3 / php form with validation - The mail goes through sort of But i only get one line in the mail which is "Fra:" and thats it
this is my as3 code

Code: (actionscript)

stop();
 
 
var emailData:URLVariables = new URLVariables();
var request:URLRequest;
var loader:URLLoader = new URLLoader();
import de.mightypirates.megazine.interfaces.IMegaZine;
 
// initialize request var with path relative to megazine.swf
 
function megazineSetup(megazine:IMegaZine):void {
    request  = new URLRequest(megazine.getAbsPath("email.php"));
    request.method = URLRequestMethod.POST;
    request.data = emailData;
    loader.load(request);
}
 
sendKnap.addEventListener(MouseEvent.CLICK, sendMail);
loader.addEventListener(Event.COMPLETE, mailSendt);
 
function sendMail(e:MouseEvent){
    if(validere()){
        statusField.text = "Sender mail, vent venligst...";
 
        emailData.navn = navnInput.text;
        emailData.email = emailInput.text;
        emailData.besked = beskedInput.text;
 
    }else{
        statusField.text = "Udfyld venligst alle felter."
    }
}
 
function validere():Boolean
{
    if(navnInput.text != "" && emailInput.text != "" && beskedInput.text != "")
    {
        return true;
    }else{
        return false;
    }	
}
 
function mailSendt(e:Event){
    trace("mail sendt")
    statusField.text = "Din besked er nu sendt!"
    navnInput.text = "";
    emailInput.text = "";
    beskedInput.text = "";
}

my php

Code: (php)

<?php
$sendTo = "name@mail.com";
$subject = "Besked fra min mail form. ";
$headers = "From: " . "Min mail form " . "<" . $_POST["email"] .">";
$message = "Fra: ". $_POST["navn"] . "\n\n" . $_POST["besked"];
 
mail($sendTo, $subject, $message, $headers);
 
?>

// fnuecke: made those code tags more readable