Animatiing when page is visible using external class

[BillChristmas]

Hello,

I've had a search through the forums and can't find an answer for this simple question.

I'm setting a page to play only when visible, placing the following code on the first frame of my fla -

Code: (actionscript3)

import de.mightypirates.megazine.IMegaZine;
import de.mightypirates.megazine.IPage;
import de.mightypirates.megazine.elements.AbstractElement;
import de.mightypirates.megazine.gui.ILibrary;
import de.mightypirates.megazine.events.MegaZineEvent;
import flash.display.MovieClip;
var pageNumber:int;
function megazineSetup(mz:*, ps:*):void {
	pageNumber = ps.number + (ps.number & 1);
	mz.addEventListener("page_change", handlePageChange, false, 0, true);
}
 
function handlePageChange(e:*):void {
	if (e.newPage==pageNumber) {
		// Now main page
		play();
	} else if (e.oldPage == pageNumber) {
		// No longer main page
		stop();
	}
}
 

This works and behaves as expected, however I would prefer to put the code in an external class - my class is shown below:

Code: (actionscript3)

package NewsLetter{
 
	import de.mightypirates.megazine.IMegaZine;
	import de.mightypirates.megazine.IPage;
	import de.mightypirates.megazine.elements.AbstractElement;
	import de.mightypirates.megazine.gui.ILibrary;
	import de.mightypirates.megazine.events.MegaZineEvent;
	import flash.display.MovieClip;
	/**
	 * ...
	 * @author 
	 */
	public class BasicAnimatedPage extends MovieClip {
 
		var pageNumber:int;
 
		public function BasicAnimatedPage() {
 
 
		}
 
		function megazineSetup(mz:*, ps:*):void {
 
			pageNumber = ps.number + (ps.number & 1);
			mz.addEventListener("page_change", handlePageChange, false, 0, true);
 
		}
 
		function handlePageChange(e:*):void {
 
			if (e.newPage==pageNumber) {
 
				// Now main page
 
				play();
 
			} else if (e.oldPage == pageNumber) {
 
				// No longer main page
 
				stop();
 
 
			}
		}
	}
}
 

This is not working - I've tried to extend from an AbstractElement also but still doesn't work.

Any help would be much appreciated as this is driving me crazy.

Thanks!

[Florian Nücke]

You'll probably have to explicitly declare the megazineSetup function as public, otherwise it won't be visible to the engine.

[BillChristmas]

Thanks a lot Florian. I'd presumed they were public by default.

Works great now.